科学データ用のテーマ 

DetailedテーマとScientificテーマは，注意深く調査するデータに適した環境を提供するよう設計されている．

完全なWolfram言語入力を表示する入力を隠す

In[1]:=

X months = DateString[{2013, #["Month"]}, "MonthNameShort"] & /@ DateRange[DateObject[{2013, 1, 1}], DateObject[{2013, 12, 31}], "Month"];

In[2]:=

X sunposKW = SunPosition[Entity["City", {"KeyWest", "Florida", "UnitedStates"}], DateRange[DateObject[{2013, 1, 1, 8}, TimeZone -> -4], DateObject[{2013, 12, 31, 8}, TimeZone -> -4], Quantity[7, "Days"]]]["Values"];

In[3]:=

X specialdatesKW = MapThread[ Labeled[#1, #2] &, {SunPosition[ Entity["City", {"KeyWest", "Florida", "UnitedStates"}], DateRange[DateObject[{2013, 1, 1, 8}, TimeZone -> -4], DateObject[{2013, 12, 31, 8}, TimeZone -> -4], "Month"]][ "Values"], months}];

In[4]:=

X sunposST = SunPosition[ Entity["City", {"Seattle", "Washington", "UnitedStates"}], DateRange[DateObject[{2013, 1, 1, 8}, TimeZone -> -7], DateObject[{2013, 12, 31, 8}, TimeZone -> -7], Quantity[7, "Days"]]]["Values"];

In[5]:=

X specialdatesST = MapThread[ Labeled[#1, #2] &, {SunPosition[ Entity["City", {"Seattle", "Washington", "UnitedStates"}], DateRange[DateObject[{2013, 1, 1, 8}, TimeZone -> -7], DateObject[{2013, 12, 31, 8}, TimeZone -> -7], "Month"]][ "Values"], months}];

In[6]:=

X analemmaPlot[theme_] := ListPlot[{sunposKW, specialdatesKW, sunposST, specialdatesST}, Joined -> {True, False, True, False}, AxesLabel -> {"azimuth(\[Degree])", "altitude(\[Degree])"}, FrameLabel -> {"azimuth(\[Degree])", "altitude(\[Degree])"}, ImageSize -> 550, PlotLabel -> Style["Analemma of The Sun at 8 AM", 18], theme, PlotLegends -> Placed[LineLegend[{"Key West", None, "Seattle", None}, Joined -> True], {Right, Top}]]

太陽のアナレンマをデフォルトテーマでプロットする．

In[7]:=

X analemmaPlot[PlotTheme -> "Default"]

Out[7]=

DetailedテーマやScientificテーマは，データに焦点を当てることができるように，格子線や色を注意深く選ぶ．

In[8]:=

X analemmaPlot[PlotTheme -> "Detailed"]

Out[8]=

In[9]:=

X analemmaPlot[PlotTheme -> "Scientific"]

Out[9]=